// Mantle Cross-Section with Tomography overlay
#include "textures.inc"

// Cameras, Lights
//------------------------------------------------------------------------------------------// 
camera {location <0,7000,-15000> look_at <0,0,0>}

//Illuminate Sides
light_source {<-10000,1000,-1500> color rgb <1,1,1>} 
light_source {<10000,1000,-1500>  color rgb <1,1,1>}  

//Illuminate Interior
light_source {<0,5000,-1000>      color rgb <1,1,1>}      
light_source {<2000,2000,-8000>   color rgb <1,1,1>}    
light_source {<0,-8000,-8000>     color rgb <1,1,1>}    
light_source {<0,8000,2000>       color rgb <1,1,1>}  
light_source {<6000,7000,1000>    color rgb <1,1,1>}   
light_source {<-6000,7000,1000>   color rgb <1,1,1>}   
     
background { color rgb <0,0,0>} 
//------------------------------------------------------------------------------------------// 
   
                    

// CRUST AND SURFACE
//------------------------------------------------------------------------------------------//
#declare Crust =    
difference { 

sphere {<0,0,0>, 6381.0   
  pigment {image_map {png "./03_Earth_GMT.png" 
  map_type 1 interpolate 2  }}
  finish {ambient 0 diffuse 1} 
  rotate<-5,-120,0>} 

sphere {<0,0,0>, 6371.0 pigment {color rgb <1,0.8,0.6>}} 
box {<0,-7000,0>, <7000,7000,-7000> pigment {color rgb <1,0.8,0.6>} finish {phong 0.8}}

}  // end difference           
//------------------------------------------------------------------------------------------//


// Righthand side mantle image
//------------------------------------------------------------------------------------------//
#declare MantleImage = 
difference {

  sphere {<0,0,0>, 6331.0 pigment {color rgb <0.82,0.87,0.611>}}    

  box {<-6371,-6371,0>, <6371,6371,-6371>    
    translate <0,6371,0> 
    pigment {image_map {png "./garnero_SEDI_earth.png"  
    map_type 0 interpolate 2}
    scale <6371,6371*2,1> rotate<0,0,0>} 
    translate <0,-6371,0>   
  }   // end box

} // end difference 
//------------------------------------------------------------------------------------------//                                           


// Lefthand side mantle image
//------------------------------------------------------------------------------------------// 
#declare MantleImage2 = 
difference {

  sphere {<0,0,0>, 6371.0 pigment {color rgb <0.82,0.87,0.611>}}    

  box {<0,-6371,6371>, <6371,6371,-6371>  
    translate <0,6371,0> 
    pigment {image_map {png "./garnero_SEDI_earth_2.png"
    map_type 0 interpolate 2}
    scale <6371,6371*2,1> rotate<0,90,0>} 
    translate <0,-6371,0>   
  }   // end box

} // end difference  
//------------------------------------------------------------------------------------------//                                           
  
// Display objects
//------------------------------------------------------------------------------------------//
#declare Earth =
union { 
     object {MantleImage}
     object {MantleImage2}                
     object {Crust} 
}

object{Earth
  rotate<0,45,0>
}  
//------------------------------------------------------------------------------------------//